Guilded Youth — 3 of 6

Section 2 (Rooms)

The Adventurers' Lounge is a room.

Instead of going in the Adventurers' Lounge, say "You're in a place for lounging, not strolling."

Your Front Porch is a room. The description is "[if unvisited]Your front door clicks behind you. You turn to the east, where the Manor beckons invisibly.[otherwise]The Manor beckons invisibly to the east.[end if]"

Your door is scenery in Your Front Porch. Understand "porch" as your door. "The unassuming house you live in is a perfect cover. No one would guess a thief lives here, even your parents."

East of Your Front Porch is End of the Street. The description of End of the Street is "[if unvisited]The map was a joke -- you don’t really need a map to find your way, even past midnight. [end if]The forest at the end of the cul-de-sac smells damp and green, leading further to the east."

Forest is scenery in End of the Street. "It's a quiet oasis to the east."

East of End of the Street is The Woods. The description of The Woods is "[if unvisited]Thanks to the full moon, you only trip once.

[end if]You’ve lived beside these woods for half of your 14 years. The way on leads east."

Before going east from End of the Street:

play mp3 sound file "crickets.mp3";

continue the action.

Trees is scenery in The Woods. Understand "woods" as Trees. "You're fairly sure they'll be sacrificed to the gods of development pretty soon."

Full Moon is scenery in The Woods. "Luna blesses the fingers of thieves, or so you believe."

Instead of climbing in Inside the manor, try silently going down.

East of the Woods is The Field. The description of the Field is "You cross the electrical tower field, feeling rather than hearing its low hum. Superstition stops you from looking up at its wires. You can see the new development in the distance, the cause of your urgent mission, its machines like sleeping behemoths. But your destination is further east."

Wires is scenery in The Field. Understand "tower" or "hum" as wires. "No. One of the few times you've heard your parents fight was over the correlation of cancer rates and electrical towers. Doesn't matter -- once you make a big score you'll move your whole family to another house."

New development is scenery in The Field. Understand "machines" and "behemoths" as New Development. "The very size of the bulldozers seems smug, like a well-fed guard dog."

East of The Field is In Front of the Manor. The description of In Front of the Manor is "[if Harry the Barbarian is joined and Inside the Manor is unvisited]It’s cloudy tonight, and the Manor is more foreboding than yesterday. You wish you brought your flashlight.

'Whew, what a dump,' says Harry. 'You sure there’s more mags in here?' [end if][If player does not have fork]Even crowded by wild brush, the grandest building in your neighbourhood still has a silent dignity. And to think: a few days from now, it’ll be erased from history.

The Manor looms to the north. You know from experience that there’s a coachhouse behind it, which you could get to by following a rough path to the northeast.[otherwise if player has fork]‘Who the heck were those guys?’ said Harry. ‘Jesus. Creepy.’

You pull out your loot and admire it, a finely designed dessert fork. Sterling silver from its weight, and beautiful in the moonlight.

Harry notices the look on your face. 'What are you, a klepto?'

You decide it's time to head home west, away from prying eyes.[end if]"

Before going north from In Front of the Manor:

if Harry is joined and player encloses fork:

say "That's enough loot for tonight.";

stop the action;

if Chris is joined and player encloses letter opener:

say "That's enough loot for tonight.";

stop the action;

if person is in Inside the Coachhouse:

say "Wisely, your instincts refuse to let you return to the scene of the crime.";

stop the action.

Before going west from In Front of the Manor:

if person is in Inside the Coachhouse:

say "Your rendezvous is to the northeast.";

stop the action.

Before going northeast from In Front of the Manor:

if offline is happening:

continue the action;

otherwise if offline5 is happening:

continue the action;

otherwise:

say "The coachhouse has already given up its meager treasures.";

stop the action.

After going north from In Front of the Manor:

try looking.

After going south from Inside the Manor:

try looking.

Before going south from Inside the Manor:

if harry is joined and player does not have fork or player does not have doorknob:

say "The Manor still has loot for the taking: you can smell it.";

stop the action;

if chris is joined and ryan is not occupied:

say "The Manor still has loot for the taking: you can smell it.";

stop the action;

if maximus is joined:

say "The Manor still has loot for the taking: you can smell it.";

stop the action.

Before asking harry about "plank/planks/bag/door":

if location is Portico of the manor:

try silently going north;

try looking;

stop the action;

else:

continue the action.

Before asking Chris about "hole/stairs/banister/staircase":

if location is Inside the manor:

try silently going up;

stop the action;

else:

continue the action.

Before asking Maximus about "hole/stairs/banister/staircase/cellar/wine":

if location is Inside the manor:

try silently going down;

stop the action;

else:

continue the action.

Before asking Ryan about "picks/locks/door/lock/pick":

if location is Inside the Manor:

try silently going east;

try looking;

stop the action;

else:

continue the action.

Before asking about:

say "Unless you really need someone to do something, you're not going to waste breath on chit-chat -- more grabbing, less gabbing.";

stop the action.

North of In Front of the Manor is Portico of the Manor. The description of Portico of the Manor is "[if Portico of the Manor is unvisited]You remember the first time you and Ryan found this place, he dared you to knock on the front door. You did him one better, opening the door and pushing it open to reveal the dark hall beyond. There was a cold-iron smell that conjured up a vision of shackles wrapped around a skeleton’s wrists. Last year, when you drank your first beer behind the portables, you recognized the smell and realized the abandoned house must have just been a drinking spot for teenagers.

You can still see the dark hall in your mind’s eye, mysterious shapes beckoning just beyond the front threshold. What were they? [end if][if harry is not joined and plank is intact][paragraph break]You won’t be plumbing the Manor's mysteries tonight: large planks of wood are nailed firmly across the front door. You curse under your breath. [else if harry is joined]Harry looks at the planks appraisingly. [else if chris is worried and ryan is joined]Chris stops when she sees the planks and the forcible entry. ‘Whoa, I didn’t know you guys broke in, I thought it was abandoned.’ Doubt flickers across her eyes. ‘My dad’s a cop. It’d kill him if I --’ She shakes her head. Then she notices the notice stapled to the door and relaxes a bit. 'Oh, well. If it's gonna be trashed anyway...' [else if paula is joined and maximus is worried]Max glances at the paper. ‘I’d like to say that my only interest in entering this building is to preserve--’

Paula cuts him off with a stagey yawn.[paragraph break][end if]You can leave the portico to the south, or enter the Manor to the north."

North of Portico of the Manor is Inside the Manor. The description of Inside the Manor is "[if Inside the Manor is unvisited]You cross the threshold into the Manor, and achieve one of your boyhood dreams. You breathe the rarefied air, not sure what it is you smell, but appreciating that you’re the first to have smelled it in... decades?

To the west you hear a shuffling and scratching. Maybe some animals got in?

You look around the space, slowly taking it in. [end if]A curving staircase, badly damaged, used to lead to the second floor. Strange shapes loom throughout the space. Hallways heading off to the east and the west.[if chris is joined and chris does not have pocket watch and Chris is in location] Chris looks around, a smile on her face. She seems intrigued by the hole in the stairs.[else if paula is joined and maximus is joined] It’s familiar ground to you now, but the others look around in awe.

[end if]"

Staircase is scenery in Inside the Manor. Understand "stairs" and "stair case" as staircase. "There's about six stairs missing, a huge hole leading down into a pitch blackness."

Northeast of In Front of the Manor is Outside the Coachhouse. The description of Outside the Coachhouse is "The double doors are large enough to drive a horse and carriage into, but one of them is missing, leaving an entryway to the north. Or you can return to the front of the Manor to the southwest."

North of Outside the Coachhouse is Inside the Coachhouse. The description of Inside the Coachhouse is "There’s a significant hole in the roof that lets in enough light to look around. You and Ryan have been in here before: until he saw a raccoon here it was practically your clubhouse. It’s pretty well picked over as a result. You can leave to the south."

The significant hole is scenery in Inside the Coachhouse. "You see a few threads of cloud in the night sky."

Up of Inside the Manor is Upstairs.

Down of Inside the Manor is Downstairs.

Before going north from Portico of the Manor:

if Harry the barbarian is joined and plank is intact:

play mp3 sound file "squeak.mp3";

say "You show Harry the problematic plank and he pulls a well-worn crowbar from his long bag. His chatter as he efficiently wrenches off the wood makes him oblivious to a slight clink you hear... then a rustle... and you'd swear it came from inside the house.

You push the door open with a creak...";

now the plank is removed;

continue the action;

try looking;

otherwise:

if plank is intact:

say "The planks get in the way.";

stop the action;

else:

continue the action.

The cellar hole is scenery in Inside the Manor. Instead of examining the cellar hole:

try going up.

Before going up from Inside the Manor:

if Chris is in Inside the Manor and chris does not have pocket watch:

say "Chris approaches the hole in the stairs and adjusts her headband.

She tests the banister first and then hangs from it. You feel your heart lurch as her legs dangle into the hole. ‘When I started gymnastics,’ she says, going hand over hand across the gap. ‘I always used to imagine using my training in an adventure.’

‘This is kind of an adventure,’ pipes up Ryan, looking at you for confirmation. ‘Right?’

She gets to the other side, and flips her feet out onto solid ground.

‘Sure, kid,’ she says. She takes a penlight out of her sweatpants pocket and disappears into the second floor darkness.";

now Chris is occupied;

remove Chris from play;

stop the action;

otherwise if maximus is joined and maximus is not occupied:

now maximus is occupied;

move rope to Inside the Manor;

say "You come up to the huge ragged hole in the stairs. Max peers into the hole. ‘Looks like it goes straight to the wine cellar,’ he says, pulling off his backpack.

All business, he pulls out a rope and attaches it to the banister, letting the end dangle down into the inky hole.";

stop the action;

otherwise:

say "You take a few steps up and can go no further. There’s about six stairs missing, a huge hole leading down into a pitch blackness[if rope is in the location] with a rope disappearing into it[end if]. The hand rail bridges the gap and seems pretty sturdy, but not enough to bet your life on.

[if harry is in the location]As you come down, Harry lets out a relieved breath. 'You don’t look like much of a long jumper.'[end if]";

stop the action.

Before going down from Inside the Manor:

if Chris is in Inside the Manor and chris does not have pocket watch:

say "Chris approaches the hole in the stairs and adjusts her headband.

She tests the banister first and then hangs from it. You feel your heart lurch as her legs dangle into the hole. ‘When I started gymnastics,’ she says, going hand over hand across the gap. ‘I always used to imagine using my training in an adventure.’

‘This is kind of an adventure,’ pipes up Ryan, looking at you for confirmation. ‘Right?’

She gets to the other side, and flips her feet out onto solid ground.

‘Sure, kid,’ she says. She takes a penlight out of her sweatpants pocket and disappears into the second floor darkness.";

now Chris is occupied;

remove Chris from play;

stop the action;

otherwise if Maximus is in Inside the Manor:

try going up;

stop the action;

otherwise if rope is in Inside the Manor:

say "You remember gym class rope climbing last year and decide against it. You’re nimble, but your upper body strength is for shit.";

stop the action;

otherwise:

say "You peer down into the inky blackness, and decide against it.";

stop the action.

Before going east from Inside the Manor for the first time:

say "The formidable door has one of those fancy crystalline doorknobs, which won't turn. It does, however, pull out in your hand and fall to the floor.

'Whoa, big guy,' Harry says, patting you on the back. 'Easy there. Don’t need to wreck the place.

The doorknob rolls to a stop on the floor.";

move the doorknob to the location;

stop the action.

After taking doorknob:

say "You turn the crystal under the light, feeling its pleasing weight in your hand. As you slip your loot in your pocket, you feel a lightness in your belly.";

continue the action.

After taking magazine:

say "You manage to peel it off the floorboards.";

continue the action.

Before going east from Inside the Manor:

if Study is locked:

if Ryan is joined and chris is occupied:

say "You and Ryan go to the door. Ryan sizes it up as he takes out his picks. ‘Keep an eye out for the cop’s daughter,’ he says, a pick hanging from his mouth as he goes about his work.

A few seconds later, the door to the east is open. Ryan can’t keep a smile off his face, and you pat him on the shoulder.";

now Study is unlocked;

else if Ryan is joined and chris is not occupied:

say "[one of]'Ready to do your magic?' you say to Ryan, motioning at the locked door.[or]You motion at the locked door again.[stopping]His eyes go big and he shakes his head, glancing over at Chris. Oh, right. That comment about her dad being a cop has him spooked. Not that it takes a lot to get him spooked.";

stop the action;

else:

say "It's locked without even a doorknob to rattle futilely.";

stop the action;

else if Study is unlocked:

if maximus is joined:

say "The door’s closed and locked again. You don’t remember closing it behind you, but maybe you did?";

stop the action.

East of Inside the Manor is the Study. The description of the Study is "This was clearly a library or office of some kind. The walls are lined with bookshelves, empty but for thick layers of dust. There’s a large desk pushed against a wall at a weird angle. You picture the owners packing up and needing to get it out of the way to get something else out of the door.

You can leave to the west." The study can be locked or unlocked. The study is locked.

Instead of pushing desk, say "A few seconds of futile pushing makes it clear why it was left here."

The bookshelves are scenery in the Study. Understand "shelves" or "books" or "book" as bookshelves. "Not a single book left behind."

West of Inside the Manor is the Hallway. The description of the Hallway is "There are birds on the wallpaper, the fragments that remain, their black eyes appearing to watch you.

Further west there looks to be a dining room."

Wallpaper is scenery in the Hallway. Understand "birds" or "eyes" or "bird" as wallpaper. "Bird eyes have always creeped you out. You are fond of magpies, though."

West of the Hallway is the Dining Room. The description of the Dining Room is "There are six people around the large table, the guys from yesterday plus a couple more. The guy with the strange bangs and suit jacket is at the head of the table beside a goth girl who’s too beautiful to look at directly. The table is laid out beautifully, a candelabra melting onto the white tablecloth, chipped plates trimmed with gold."

Before going west from Hallway:

if harry is joined:

say "You make your way towards the dining room, you start to hear hushed voices. Harry kicks something that hits the wall with a metal sound. Your heart jumps as the low voices in the other room pause.

When they start up again you back slowly away, but not before pocketing the object Harry kicked.

You escape through the front door and emerge...";

move fork to player;

play mp3 sound file "treasuregetting.mp3";

move player to In front of Manor;

move Harry to In front of Manor;

stop the action;

otherwise if chris is joined:

say "[one of]You inch forward a bit and try to catch a glimpse of the dining room occupants. You dip in and out, catching a glimpse of a long haired one, a guy with some kind of suit jacket, and two or three more. They appear to be setting the table...?

You feel Chris’s hand on your arm, pulling you back.

The clink of dinner plates and cutlery cover up the sounds of conversation.

‘...definitely candles, it gives...’

Chris lets go of your arm.[or]You lean in and listen in a bit more.

‘...as if we’re the lords of the Manor. The pinnacle of suburban decadence. Rome before the malls moved in.’

Chris gives you a confused look, and you shrug.[or]No way are you going in there without at least two people to back you up. 'Probably we should get out while the getting's good,' Chris whispers.[stopping]";

stop the action.

Instead of asking chris about "bulge/gleam/gold/golden" during offline3, say "She shrugs, failing to keep a grin off her face."

Before going west from Inside the Manor:

if ryan is joined:

if player does not have letter opener:

say "'Uh,' Ryan says, 'Sounds like there's people there. Why don't we search the other rooms first?'";

stop the action;

otherwise if ryan is in the location:

say "When Ryan sees you heading towards the noise instead of away, he makes for the exit.

‘Um... band practice, gotta go... nicetomeetyoubye!’ he says. When he gets out of the house he abandons all dignity and just starts running.

Chris gives you a sly smile and walks along with you.";

move Ryan to Adventurers' Lounge;

now Ryan is occupied;

now Ryan is not joined;

play mp3 sound file "unjoined.mp3";

otherwise if Harry is joined:

if player does not have doorknob:

say "Based on the animal (?) sounds you heard earlier, you decide to leave that for last.";

stop the action;

otherwise if Paula is joined and Maximus is not in location:

move Paula to Dining Room;

say "You stop just outside the dining room in the hallway and peek in. There’s a whole dinner party going on inside. You whisper to Paula that you recognize the guy from yesterday.

‘Yes,’ she says, her face flooding with emotion. ‘I recognize him too.’

Before you can contest, she adjusts her hat, squares her shoulders, and strides into the dining room... taking you with her.";

move player to Dining Room;

refresh avatar illustrations;

stop the action;

otherwise if Maximus is joined and maximus is not occupied:

say "Max stops you. 'First things first: let's find the wine cellar.'";

stop the action.

Before listening while location is Hallway:

if Chris is joined:

try silently going west;

stop the action;

else:

continue the action.

Before going west from In Front of Manor:

if player has a fork:

now harry is not joined;

remove harry from play;

say "As you head for home, Harry keeps on with his blather. ‘Oh, oh yeah. Your Guild character. Don't you think you take it a little too seriously?'[paragraph break]You don't dignify that with an answer.[paragraph break]'Hey how can you be a thief with a good alignment anyway? Isn’t that the opposite?’

You walk faster and leave the Barbarian to struggle along with his large bag, and his ignorance, alone.";

say "[paragraph break]***Press any key to continue***";

wait for any key;

eval "$('#vorple').empty()";

stop the action;

otherwise:

say "[if player has pocket watch]She's a quick one, and you lose track of her.[else]You're not going home before you get some decent loot.[end if]";

stop the action.

After going east from the Field:

try looking;

if Chris is joined and ryan is not occupied:

now Chris is not occupied;

say "There’s a girl in a track suit in front of the Manor. You keep it cool and introduce yourself.

‘Hey I’m Chris,’ she says, then trains her dark eyes on your friend. ‘And I guess you’re Ryan?’

Ryan, as usual in the presence of a non-boy, is motionless, so you nod for him.";

otherwise if Paula is joined:

now Paula is not occupied;

say "Paula -- you assume it’s Paula, though she looks more goth than witch -- takes one last drag on her smoke before killing it under a creeper boot.

‘Hello, boys,’ says Paula in a soft, deep voice. ‘You ready to knock over this joint?’

You nod.

Paula turns toward the Manor and begins to pull on lacy gloves.".

Before going from Portico of the Manor:

if chris is joined:

now chris is not worried;

if maximus is joined:

now maximus is not worried;

continue the action.

After going west from study:

if player has letter opener and chris is occupied and ryan is joined:

now chris is not occupied;

move pocket watch to chris;

move chris to location of player;

say "‘There you guys are,’ Chris says grumpily as you come out. She gets up from the bottom of the stairs, where she’s been sitting.

She’s got her arms crossed and a funny look on her face. Despite her efforts, you notice there’s a small bulge in her jacket.

You’re about to ask her about it when there’s a smashing sound to the west, followed by a peel of laughter.

Ryan nearly jumps out of his skin.";

otherwise:

continue the action.

Instead of going during DirtyKissing:

say "That golden gleam stops you in your tracks."